Arduino IDE Quickstart

Drop your credentials in a header

Create a new sketch (File → New Sketch), save it as quickstart_pub, then add a tab called credentials.h (click the small down-arrow in the tab bar →New Tab). Paste in your values from the dashboard:

#define WIFI_SSID   "YourWiFiName"
#define WIFI_PASS   "YourWiFiPassword"

#define MQTT_HOST   "mqtt.ohioiot.com"
#define MQTT_PORT   8883
#define MQTT_USER   "larry"
#define MQTT_PASS   "your_mqtt_password"

The publish sketch

Switch to the main quickstart_pub.ino tab and paste this in. It connects to WiFi, connects to MQTT, publishes a single value, and sits idle.

#include <WiFi.h>
#include <WiFiClientSecure.h>
#include <PubSubClient.h>
#include "credentials.h"

WiFiClientSecure wifi;
PubSubClient mqtt(wifi);

void setup() {

    Serial.begin(115200);
    Serial.println();

    // ----- wifi (blocking) -----
    WiFi.begin(WIFI_SSID, WIFI_PASS);
    Serial.print("wifi");
    while (WiFi.status() != WL_CONNECTED) {
        Serial.print(".");
        delay(500);
    }
    Serial.println(" connected");

    // ----- mqtt (blocking) -----
    wifi.setInsecure();              // quickstart only — see warning below
    mqtt.setServer(MQTT_HOST, MQTT_PORT);

    Serial.print("mqtt");
    while (!mqtt.connected()) {
        Serial.print(".");
        if (mqtt.connect("quickstart-pub", MQTT_USER, MQTT_PASS)) break;
        delay(2000);
    }
    Serial.println(" connected");

    // ----- publish one value -----
    String topic = String(MQTT_USER) + "/dev1/numb/temperature/celsius";
    mqtt.publish(topic.c_str(), "23.5");
    Serial.println("published 23.5 to " + topic);
}

void loop() {
    mqtt.loop();
}

Flash and verify

Plug in your ESP32, pick the right port under Tools → Port, and hit Upload. Open Tools → Serial Monitor at 115200. You should see:

wifi... connected
mqtt.. connected
published 23.5 to larry/dev1/numb/temperature/celsius

Open the dashboard. Under Devices you'll see dev1 with a temperature reading of 23.5.

The subscribe sketch

Make a second sketch (File → New Sketch), save it as quickstart_sub, and add the same credentials.h tab — copy-paste the file from the first sketch.

Paste this into quickstart_sub.ino:

#include <WiFi.h>
#include <WiFiClientSecure.h>
#include <PubSubClient.h>
#include "credentials.h"

WiFiClientSecure wifi;
PubSubClient mqtt(wifi);

void onMessage(char* topic, byte* payload, unsigned int length) {
    Serial.print("got [");
    Serial.print(topic);
    Serial.print("] ");
    for (unsigned int i = 0; i < length; i++) Serial.print((char)payload[i]);
    Serial.println();
}

void setup() {

    Serial.begin(115200);
    Serial.println();

    // ----- wifi (blocking) -----
    WiFi.begin(WIFI_SSID, WIFI_PASS);
    Serial.print("wifi");
    while (WiFi.status() != WL_CONNECTED) {
        Serial.print(".");
        delay(500);
    }
    Serial.println(" connected");

    // ----- mqtt (blocking) -----
    wifi.setInsecure();
    mqtt.setServer(MQTT_HOST, MQTT_PORT);
    mqtt.setCallback(onMessage);

    Serial.print("mqtt");
    while (!mqtt.connected()) {
        Serial.print(".");
        if (mqtt.connect("quickstart-sub", MQTT_USER, MQTT_PASS)) break;
        delay(2000);
    }
    Serial.println(" connected");

    // ----- subscribe to the same topic the pub sketch wrote to -----
    String topic = String(MQTT_USER) + "/dev1/numb/temperature/celsius";
    mqtt.subscribe(topic.c_str());
    Serial.println("subscribed to " + topic);
}

void loop() {
    mqtt.loop();
}

The two sketches use different client IDs (quickstart-pub vs quickstart-sub) so the broker keeps them as separate connections. If you reused the same ID, the second connect would kick the first off.

Flash and watch the round trip

With your ESP32 still plugged in, hit Upload on quickstart_sub. The Serial Monitor will show:

wifi... connected
mqtt.. connected
subscribed to larry/dev1/numb/temperature/celsius

Now publish to that topic. Easiest path: open the dashboard, find dev1, and click the temperature value to send a manual publish. (Or re-flash the publish sketch from Step 2 — it'll publish once on every boot.)

The Serial Monitor on the subscribe sketch should print:

got [larry/dev1/numb/temperature/celsius] 23.5